From d067bc2cfcdf991faa84572c9024b329659d5066 Mon Sep 17 00:00:00 2001
From: Yozora <yozora.sora.mikazuki@gmail.com>
Date: Sat, 6 Aug 2016 12:50:27 +0200
Subject: [PATCH] Added version-agnostic uninstaller for Windows

This uninstaller.bat removes BetterDiscord from all app-* folders in %localappdata%\Discord\ and restarts Discord afterwards.
---
 misc/uninstall.bat | 46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 misc/uninstall.bat

diff --git a/misc/uninstall.bat b/misc/uninstall.bat
new file mode 100644
index 0000000..8e25149
--- /dev/null
+++ b/misc/uninstall.bat
@@ -0,0 +1,46 @@
+@ECHO off
+
+:prompt
+set /P c=Are you sure you want to uninstall BetterDiscord [Y/N]? 
+echo.
+if /I "%c%" EQU "Y" goto :removeBetterDiscord
+if /I "%c%" EQU "N" goto :eof
+goto :prompt
+
+:removeBetterDiscord
+echo Removing BetterDiscord...
+echo.
+
+:: Delete %appdata%\BetterDiscord
+call:deleteFolder %appdata%\BetterDiscord
+
+:: Remove BetterDiscord from all app versions
+for /d %%G in ("%localappdata%\Discord\app-*") do (
+    call:deleteFolder "%%G\resources\node_modules\BetterDiscord"
+    call:deleteFolder "%%G\resources\app"
+    SET latestDiscordVersion=%%G
+)
+
+goto:end
+
+:: Checks whether a folder exists and deletes it if it does
+:deleteFolder
+if exist "%~1" (
+    @RD /S /Q "%~1"
+    echo Folder "%~1" removed.
+) else (
+    echo Folder "%~1" does not exist.
+)
+goto:eof
+
+:end
+echo.
+echo Restarting Discord...
+taskkill /f /im Discord.exe 1>nul 2>nul
+"%localappdata%\Discord\Update.exe" --processStart Discord.exe
+
+echo.
+echo BetterDiscord has been removed!
+echo.
+
+pause
\ No newline at end of file