# Maintainer: Les De Ridder <aur@lesderid.net>
_pkgname=lokinet
pkgname=${_pkgname}-git
pkgver=v0.3.1.r218.a8e3f79
pkgrel=1
pkgdesc="A private, decentralized and Market based Sybil resistant overlay network"
arch=('x86_64')
url="https://loki.network/"
license=('custom:zlib')
depends=('bash' 'libcap')
makedepends=('git' 'cmake' 'rapidjson')
provides=("lokinet")
source=("$_pkgname::git+git://github.com/loki-project/loki-network" 'lokinet.sysusers' 'lokinet.tmpfiles' 'lokinet.install')
sha256sums=('SKIP' 'b8c5648e95d3725ecba246dc702856e691d6e0688554654b2712ffdea16b1c6f' 'a67f1eb92176c85dc25b2e41fb796a8c8334270bb230ccfdf9320d0a8552ca93' 'f6a0bdc4504039318fbacaf76bfdcca764440312af2c4f4f19b045c7db7ee865')
install=lokinet.install

pkgver() {
	cd "$srcdir/$_pkgname"

	printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
}

prepare() {
	cd "$srcdir/$_pkgname"

	sed -i 's/sbin/bin/g;s/debian-//' debian/lokinet.service
	sed -i 's/CMAKE_CXX_STANDARD 11/CMAKE_CXX_STANDARD 17/' CMakeLists.txt
}

build() {
	cd "$srcdir/$_pkgname"

	grep -q avx2 /proc/cpuinfo && AVX2=ON || AVX2=OFF

	make JSONRPC=ON CLANG=ON AVX2=$AVX2
}

package() {
	cd "$srcdir/$_pkgname"

	install -Dm755 build/lokinet "$pkgdir/usr/bin/lokinet"
	install -Dm755 build/rcutil "$pkgdir/usr/bin/lokinet-rcutil"
	install -Dm755 lokinet-bootstrap "$pkgdir/usr/bin/lokinet-bootstrap"

	install -Dm644 debian/${_pkgname}.service "$pkgdir/usr/lib/systemd/system/${_pkgname}.service"

	install -Dm644 debian/${_pkgname}.1 "$pkgdir/usr/share/man/man1/${_pkgname}.1"

	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

	install -Dm644 $srcdir/${_pkgname}.sysusers "$pkgdir"/usr/lib/sysusers.d/${_pkgname}.conf
	install -Dm644 $srcdir/${_pkgname}.tmpfiles "$pkgdir"/usr/lib/tmpfiles.d/${_pkgname}.conf
}