lokinet: Add PKGBUILD

lokinet/.gitignore

@@ -0,0 +1,5 @@
+*
+!.gitignore
+!PKGBUILD
+!lokinet.sysusers
+!lokinet.tmpfiles

lokinet/PKGBUILD

@@ -0,0 +1,51 @@
+# Maintainer: Les De Ridder <aur@lesderid.net>
+_pkgname=lokinet
+pkgname=${_pkgname}-git
+pkgver=v0.2.3.rc1.r0.bb3bed1
+pkgrel=1
+pkgdesc="A private, decentralized and Market based Sybil resistant overlay network"
+arch=('x86_64')
+url="https://loki.network/"
+license=('custom:zlib')
+depends=('bash' 'libcap')
+makedepends=('git' 'cmake')
+provides=("lokinet")
+source=("$_pkgname::git+git://github.com/loki-project/lokinet-builder.git" 'lokinet.sysusers' 'lokinet.tmpfiles')
+sha256sums=('SKIP' 'b8c5648e95d3725ecba246dc702856e691d6e0688554654b2712ffdea16b1c6f' 'a67f1eb92176c85dc25b2e41fb796a8c8334270bb230ccfdf9320d0a8552ca93')
+
+pkgver() {
+	cd "$srcdir/$_pkgname/deps/llarp"
+
+	printf "%s" "$(git describe --long | sed 's/\([^-]*-\)g/r\1/;s/-/./g')"
+}
+
+prepare() {
+	cd "$srcdir/$_pkgname"
+
+	git submodule update --init --recursive
+
+	sed -i 's/sbin/bin/g;s/debian-//' debian/lokinet.service
+}
+
+build() {
+	cd "$srcdir/$_pkgname"
+
+	make
+}
+
+package() {
+	cd "$srcdir/$_pkgname"
+
+	install -Dm755 build/native/lokinet "$pkgdir/usr/bin/lokinet"
+	install -Dm755 build/native/rcutil "$pkgdir/usr/bin/lokinet-rcutil"
+	install -Dm755 lokinet-bootstrap "$pkgdir/usr/bin/lokinet-bootstrap"
+
+	install -Dm644 debian/${_pkgname}.service "$pkgdir/usr/lib/systemd/system/${_pkgname}.service"
+
+	install -Dm644 debian/${_pkgname}.1 "$pkgdir/usr/share/man/man1/${_pkgname}.1"
+
+	install -Dm644 deps/llarp/LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
+
+	install -Dm644 $srcdir/${_pkgname}.sysusers "$pkgdir"/usr/lib/sysusers.d/${_pkgname}.conf
+	install -Dm644 $srcdir/${_pkgname}.tmpfiles "$pkgdir"/usr/lib/tmpfiles.d/${_pkgname}.conf
+}

lokinet/lokinet.sysusers

@@ -0,0 +1 @@
+u lokinet - "lokinet daemon user" /var/lib/lokinet

lokinet/lokinet.tmpfiles

@@ -0,0 +1 @@
+d /var/lib/lokinet 0750 lokinet lokinet